***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Dec. 26, 2025                                                        *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJD70N10SA-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs     s1    s2    205u TC=3m
Rg     g1    g2    8.730e-1
M1     d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=240  VTO=2.8  LEVEL=3  VMAX=5e4 NFS=4.8e11  GAMMA=0.6)
Rd     d1    d2   5.246e-3    TC=6.000e-3,16u
Dbd     s2    d2    Dbt
.MODEL   Dbt   D(BV=110  TBV1=5.150e-4 TBV2=-3.800e-7  CJO=1.713e-9  M=2.060  VJ=6.393e1)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=1.465e-11 N=1.077  RS=4e-8  EG=1.15  TT=20n  IKF=9.345 TIKF=-1.850e-3)
Rdiode  d1  21    1.153e-3 TC=3.000e-3
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   1.688e-9
.MODEL     DGD    D(CJO=1.688e-9   M=1.495   VJ=5.437)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    2.353e-9
.ENDS PJD70N10SA-AU
*$
